Language Guide

system::config() { ... };           // server.cfg
player::connect(int playerid) { };  // callback
function add(int a, int b) { return a + b; };
let total = 0;                      // variable

let hp = 100;       // int
let speed = 1.5;    // float
let name = "CJ";    // string
let online = true;  // bool

hp = 90;            // reassign
hp += 5;            // compound: += -= *= /= %=

player::command("/rank", int score) {
    if (score >= 100) {
        SendClientMessage(playerid, "Veteran");
    } else if (score >= 50) {
        SendClientMessage(playerid, "Regular");
    } else {
        SendClientMessage(playerid, "Rookie");
    }
};

// while
let i = 0;
while (i < 10) {
    i += 1;
}

// do / while: runs at least once
do {
    i -= 1;
} while (i > 0);

// C-style for
for (let n = 0; n < 5; n += 1) {
    if (n == 3) { break; }
}

// iterate an array
let names = ["amy", "bob", "cid"];
for (let name in names) {
    SendClientMessage(playerid, "Hi {name}");
}

// iterate an array with the index
for (let index, name in names) {
    SendClientMessage(playerid, "{index}: {name}");
}

// iterate a map (keys are visited in sorted order)
let scores = { "amy": 10, "bob": 20 };
for (let key in scores) {
    SendClientMessage(playerid, "{key} = {scores[key]}");
}

// skip some iterations
for (let n = 0; n < 20; n += 1) {
    if (n % 2 == 0) { continue; }
    if (n > 15) { break; }
}

player::command("/class", int id) {
    switch (id) {
        case 0:
            SendClientMessage(playerid, "Medic");
        case 1:
            SendClientMessage(playerid, "Police");
        default:
            SendClientMessage(playerid, "Civilian");
    }
};

let scores = [10, 20, 30];
let player = { "name": "CJ", "score": 0 };

scores[0] = 15;
player["score"] = 42;

let first = scores[0];
let n = len(scores);

push(scores, 40);            // mutate in place: [10, 20, 30, 40]
let last = pop(scores);      // 40, scores is now [10, 20, 30]
let part = scores[1:3];      // [20, 30]
let sorted = sort([3, 1, 2]); // [1, 2, 3]

let hex = 0xFF00FF00;   // hex int
let wait = 500ms;       // duration -> milliseconds
let pos = [1.0, 2.0, 3.0];
let meta = { "hp": 100 };

// line comment
/* block comment
   spanning lines */

#include <knight>              // optional; natives are built in
#include "lib/shared.sa"       // include another file

function clampHealth(float value) {
    if (value < 0.0) { return 0.0; }
    if (value > 100.0) { return 100.0; }
    return value;
}

player::spawn(int playerid) {
    SetPlayerHealth(playerid, clampHealth(150.0));
};

function spawnAt(Player target, float x, float y, float z = 3.0) { ... }
function total(int first, ...rest) {
    let sum = first;
    for (let n in rest) { sum += n; }
    return sum;
}

spawnAt(playerid, 100.0, 200.0);       // z defaults to 3.0
total(1, 2, 3, 4);                     // 10

const MAX_HP = 100;
const RATIO: float = 0.5;

function cap(float hp) { return hp > MAX_HP ? MAX_HP : hp; }

function add(int a, int b) { return a + b; }
function isBig(int n) { return n > 10; }

let sum = CallRemoteFunction("add", 2, 3);      // 5
let big = CallLocalFunction("isBig", 50);       // 1
let x = CallRemoteFunction("missing");          // 0 (logged)

let total = 0;                  // module scope

player::connect(int playerid) {
    let local = 5;              // callback scope
    total = total + local;      // module variable is writable
};